צור קשר צור קשר   support@livedns.co.il  |  03-9700600  | 
אודות
הספק המושלם לפתרונות ענן ואחסון אתרים
www.
מאגרי מידע מאגרי מידע
קו הפרדה

כיצד ניתן לשלוח מייל עם הגדרת עדיפות ואישור קריאה באמצעות CDO?


<!-- 
METADATA 
TYPE="typelib" 
UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" 
NAME="CDO for Windows 2000 Library" 
--> 

<% 


StrHtmlBody="<b>Your Html Text Body</b>"
strSubject="Mail Test"
ReceiptTo="YourEmail@address.com"
strFrom="YourEmail@address.com"
strTo="ToEmail@address.com"

 

Set objEmail = CreateObject("CDO.Message")

 objEmail.From =strFrom
objEmail.To = strTo
objEmail.Subject = strSubject

' Using Pickup
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1
objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory") = "c:\inetpub\mailroot\pickup"

' using SMTP
'objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")= "YourSmtpServer"
'objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")= 25


objEmail.Configuration.Fields.Update

objEmail.Bodypart.ContentMediaType = "text/html"
objEmail.Bodypart.ContentTransferEncoding = "7bit"
objEmail.Bodypart.Charset= "windows-1255"

' for Outlook:
objEmail.Fields.Item(cdoImportance) = 2 
objEmail.Fields.Item(cdoPriority) = 1 
 
' for Outlook Express:
objEmail.Fields.Item("urn:schemas:mailheader:X-Priority") = 1

objEmail.Fields(cdoDispositionNotificationTo) = ReceiptTo 
objEmail.Fields(cdoReturnReceiptTo) = ReceiptTo 


objEmail.Fields.Update
 
SET Stm = objEmail.Bodypart.GetDecodedContentStream
Stm.WriteText StrHtmlBody
Stm.Flush
objEmail.Send
set objEmail=nothing


%>




נכתב ע"י: LiveDns Ltd - אחסון אתרים  אחסון אתרים | תאריך: 10/1/2009
צפיות: 5785

חזרה לדף קודם